Pretty sure the following formula will do what you want:

Brief summary of algorithm:

use the formula evaluation tool to tease it apart and see how it works in detail. As noted in the comments, you will see that the 99 puts a limit on the number of characters you can return. This might have to be altered if your returned data might be longer

• remove everything up to and including ://
  


• replace the 2nd from last dot with a rarely used character


• use the FIND function to locate that substitution so as to generate the Start number for the MID function

=MID(A1,FIND("://",A1)+2+FIND(CHAR(1),SUBSTITUTE("." &MID(A1,FIND("://",A1)+3,99),".",CHAR(1),LEN("." &A1)-LEN(SUBSTITUTE("." &A1,".",""))-1)),99)

=RIGHT(D2, 

 LEN(D2) - FIND("", SUBSTITUTE(D2, ".", "", LEN(D2) - LEN(SUBSTITUTE(D2, ".", "")) - 1))

The explanation:

First, we get the number of periods with this simple trick:

1. We determine the length of the the full text:
   =LEN(D2) (see column E in the picture)
   


2. We determine the length of the same text but with all periods removed:
   =LEN(SUBSTITUTE(D2, ".", "")) (see column F in the picture)
   


3. The difference will be the number of periods:
   =LEN(D2) - LEN(SUBSTITUTE(D2, ".", "")) (see column G in the picture)
   

Second, as we know the number of periods, we are able to determine the
occurrence number of the last but one period. For example, if number of periods
is 5, the last but one period has the occurrence number 4:

• 
  =LEN(D2) - LEN(SUBSTITUTE(D2, ".", "")) - 1 (see column H in the picture)
  

Third, we use this as the 4-th parameter of the SUBSTITUTE() function
to replace that occurrence of period with the symbol:

• 
  =SUBSTITUTE(D2, ".", "", LEN(D2) - LEN(SUBSTITUTE(D2, ".", "")) - 1) (see column I in the picture)
  

Fourth, we determine the position of that symbol () with the FIND() function:

• 
  =FIND("", SUBSTITUTE(D2, ".", "", LEN(D2) - LEN(SUBSTITUTE(D2, ".", "")) - 1)) (see column J in the picture)
  

Fifth, as we know the position of that symbol () and the length of the full text,
we may determine the number of remained symbols, i. e. symbols after . For examle,
if the length of the full text is 5 and the position of is 3, there are 2 remained symbols:

• 
  =LEN(D2) - FIND("", SUBSTITUTE(D2, ".", "", LEN(D2) - LEN(SUBSTITUTE(D2, ".", "")) - 1)) (see column K in the picture)
  

Finally, we use it as the second parameter of the RIGHT() function:

• 
  =RIGHT(D2, LEN(D2) - FIND("", SUBSTITUTE(D2, ".", "", LEN(D2) - LEN(SUBSTITUTE(D2, ".", "")) - 1)) (see column L in the picture)
  

and it is the final formula.

Note:

The last example in the question has no second but one period (in contradiction with the title of the question). To include such possibility, add . after http://, i. e. substitute all D2 in formula with

=SUBSTITUTE(D2, "//", "//.")

=IF(LEN(A1)-LEN(SUBSTITUTE(A1, ".", "", 2)), SUBSTITUTE(TRIM(RIGHT(SUBSTITUTE(A1, ".", REPT(" ", LEN(A1))), LEN(A1)*2)), " ", "."), IFERROR(RIGHT(A1, LEN(A1)-FIND("://", A1)-2), A1))

How does this work?

First we have an IF statement that lets us treat things differently if there's one (or less) periods, or if there are at least 2 periods.

Our logical test is to check if there's a second period: LEN(A1)-LEN(SUBSTITUTE(A1, ".", "", 2))

This will return 0 if it can't find 2 periods in the string, or 1) if there are 2 or more.

We then put the 'if there are 2 or more periods' formula first, and the 'if there are less than 2 periods' formula second, but since the latter is much simpler, I'll cover it first.

If there are less than 2 periods:

If there is one or zero periods, then we need to remove the text up to and including the :// at the beginning, so we'll find the position of the :// and take only the text after it: RIGHT(A1, LEN(A1)-FIND("://", A1)-2)

Just in case there is data that doesn't start with a protocol ending in :// we should wrap this with an IFERROR and get the whole original string instead of a #VALUE error, this ends up being: IFERROR(RIGHT(A1, LEN(A1)-FIND("://", A1)-2), A1)

If there are (at least) 2 periods

Now that we have the simpler cases out of the way, lets look at what happens when there are 2 (or more) periods: SUBSTITUTE(TRIM(RIGHT(SUBSTITUTE(A1, ".", REPT(" ", LEN(A1))), LEN(A1)*2)), " ", ".")

Let's break that down:

1. We replace all periods with a large number of spaces (as many as there are characters in the whole original string): SUBSTITUTE(A1, ".", REPT(" ", LEN(A1)))
   


2. We take only the end of that, specifically twice the length of the original string. This gives us the last two parts, and a bunch of spaces before and between the 2 parts: RIGHT(<step 1>, LEN(A1)*2)
   
   Note: If you wanted to include the next section as well, you'd change *2 to *3.


3. We remove all the extraneous spaces using TRIM, leaving us with only a single space, where the one remaining period is supposed to be: TRIM(<step 2>)
   


4. We replace that one remaining space with a .: SUBSTITUTE(<step 3>, " ", ".")
   

So our whole formula is:
=IF(LEN(A1)-LEN(SUBSTITUTE(A1, ".", "", 2)), SUBSTITUTE(TRIM(RIGHT(SUBSTITUTE(A1, ".", REPT(" ", LEN(A1))), LEN(A1)*2)), " ", "."), IFERROR(RIGHT(A1, LEN(A1)-FIND("://", A1)-2), A1))

The usual formula uses SUBSTITUTE() to replace all the characters of interest, the period in this case, with strings that are arbitrarily long compared to the data one could reasonably find in a cell.

For example, if the longest a set of characters between periods could be is, oh, 95 in your expected data, then a replacement string of, say, 250 "spaces" replacing each period would work nicely.

Then wrap the SUBSTITUTE() function in a RIGHT() function. If your result should only be 3 characters long, you need 253 characters at the right. You have 502 before you pick up anything undesired. If the full 95 expected plus 250 spaces plus another 95 will result, you need 420 characters to cover yourself. But still have 502 you can take without taking undesired characters. So pick a number between the max you expect, 420 and the mas you can use, 502: perhaps 490, and take the rightmost 490 characters with the RIGHT() function.

Now wrap the SUBSTITUTE() function around that, this time replacing spaces with "" so all the spaces introduced go away and you have your desired result.

If spaces can be in the desired result, use a different character which won't be. Something odd looking in the font's list of possible characters. Perhaps ¬ (Alt-01452). Or don't risk it and use that instead of ever using spaces.

Don't type out 250 spaces either. Use the REPT() function in the first (interior) SUBSTITUTE() function to type the character of choice once but get 250 of them!

There are other approaches but they usually involve knowing how many of the character there can be. For instance, your data could be well-formed enough to know there are always 4 periods. Then these work nicely. But if it could vary, 3 here, 7 there, well...

The above is "brutal" rather than "elegant" but who really cares? Simple in conception so easy to use and it does your trick.